home *** CD-ROM | disk | FTP | other *** search
/ Softdisk Supreme / Softdisk Supreme.iso / pc / DSK Files / 0-49 / SD003b.dsk / HEADLINES.bas < prev    next >
BASIC Source File  |  2003-06-12  |  5KB  |  119 lines
  1. 10  REM  *** INSTELLAR NEWS HEADLINES ***
  2. 20  REM  *** 5-18-81 FIRST VERSION    ***
  3. 30 D$ =  CHR$(4)
  4. 35  IF Z >10  THEN  PRINT "SORRY. MAXIMUM OF 10 HEADLINES AT A TIME.": PRINT : GOTO 130
  5. 40  REM  PRINT MENU
  6. 50  HOME : PRINT 
  7. 55  PRINT  TAB( 5)"1   PRINT HEADLINES"
  8. 60  PRINT  TAB( 5)"2   ADD TO DATA FILES"
  9. 65  PRINT  TAB( 5)"3   CREATE NEW DATA FILE"
  10. 66  PRINT  TAB( 5)"4   QUIT"
  11. 70  PRINT : PRINT "ENTER SELECTION NUMBER - ";: GET Z: PRINT Z
  12. 72  PRINT 
  13. 75  IF Z <1  OR Z >4  THEN 70
  14. 80  IF Z = 1  THEN 100
  15. 85  IF Z = 2  THEN 1000
  16. 86  IF Z = 3  THEN 2000
  17. 90  END 
  18. 100  REM  PRINT HEADLINES
  19. 110  HOME : PRINT : INVERSE : PRINT "EXTRA     EXTRA     EXTRA     EXTRA     ": PRINT 
  20. 120  PRINT  TAB( 11)"READ ALL ABOUT IT!!!          ": NORMAL : PRINT : PRINT 
  21. 130  INPUT "HOW MANY HEADLINES DO YOU WANT TO SEE?";Z
  22. 135  IF Z >10  THEN  PRINT "SORRY. MAXIMUM OF 10 HEADLINES AT A TIME": PRINT : GOTO 130
  23. 140  PRINT : PRINT "ONE MOMENT, PLEASE, WHILE I SET THE TYPE.": PRINT 
  24. 150  PRINT D$"OPEN NOUNS,L40"
  25. 155  PRINT D$"READ NOUNS,R0": INPUT N
  26. 160  PRINT D$"OPEN VERBS,L40"
  27. 165  PRINT D$"READ VERBS,R0": INPUT V
  28. 170  PRINT D$"OPEN ADJECTIVES,L40"
  29. 175  PRINT D$"READ ADJECTIVES,R0": INPUT A
  30. 180  PRINT D$
  31. 190  FOR I = 1 TO Z
  32. 200 A1 =  INT( RND(1) *A +1)
  33. 205 V1 =  INT( RND(1) *V +1)
  34. 210 N2 =  INT( RND(1) *N +1)
  35. 211 N1 =  INT( RND(1) *N +1)
  36. 212  PRINT D$"READ NOUNS,R"N1: INPUT N1$
  37. 215  PRINT D$"READ NOUNS,R"N2: INPUT N$
  38. 220  PRINT D$"READ VERBS,R"V1: INPUT V$
  39. 225  PRINT D$"READ ADJECTIVES,R"A1: INPUT A$
  40. 230  PRINT D$
  41. 240 H$(I) = N$ +" " +V$ +" " +A$ +" " +N1$
  42. 250  NEXT 
  43. 260  PRINT D$"CLOSE"
  44. 270  PRINT "HERE ARE YOUR HEADLINES"
  45. 280  PRINT D$"PR#1"
  46. 285  PRINT 
  47. 290  PRINT "EXTRA          EXTRA          EXTRA          EXTRA          EXTRA": REM  10 SPACES
  48. 295  PRINT : PRINT  TAB( 25)"READ ALL ABOUT IT!!!": PRINT : PRINT 
  49. 300  FOR I = 1 TO Z
  50. 310  PRINT H$(I): PRINT 
  51. 320  NEXT 
  52. 330  PRINT D$"PR#0": PRINT 
  53. 340  PRINT : INPUT "DO YOU WANT MORE HEADLINES?";Z$
  54. 350  IF  LEFT$(Z$,1) = "Y"  THEN 130
  55. 360  GOTO 50
  56. 1000  REM  ADD TO DATA FILES
  57. 1010  HOME : INVERSE : PRINT "(ADD TO DATA FILES)": NORMAL : PRINT : PRINT 
  58. 1020  PRINT "YOU MAY ADD DATA TO ONE OF THREE"
  59. 1025  PRINT "CATAGORIES.": PRINT 
  60. 1030  PRINT  TAB( 5)"1   NOUNS"
  61. 1040  PRINT  TAB( 5)"2   VERBS"
  62. 1050  PRINT  TAB( 5)"3   ADJECTIVES"
  63. 1060  PRINT  TAB( 5)"4   QUIT"
  64. 1070  PRINT : PRINT "ENTER SELECTION NUMBER - ";: GET Z: PRINT Z
  65. 1080  IF Z <1  OR Z >4  THEN 1070
  66. 1090  IF Z = 1  THEN F$ = "NOUNS"
  67. 1095  IF Z = 2  THEN F$ = "VERBS"
  68. 1100  IF Z = 3  THEN F$ = "ADJECTIVES"
  69. 1110  IF Z = 4  THEN 50
  70. 1111  HOME : PRINT "ENTERIES MAY BE A SINGLE WORD OR A"
  71. 1112  PRINT "GROUP OF WORDS.  THE MORE DESCRIPTIVE"
  72. 1113  PRINT "THE ENTERIES, THE BETTER.": PRINT : PRINT 
  73. 1114  INVERSE : PRINT "EXAMPLE:": NORMAL 
  74. 1115  PRINT  TAB( 5)"ALIEN"
  75. 1116  PRINT  TAB( 5)"SHIPLOAD OF VEGAN COLONISTS"
  76. 1117  PRINT  TAB( 5)"BUYS CONTROL OF"
  77. 1118  PRINT  TAB( 5)"SMOKE TRAILING"
  78. 1119  VTAB 23: PRINT "PRESS RETURN TO CONTINUE";: GET A$
  79. 1120  HOME : PRINT "TO STOP ENTERING, TYPE 'END'.": PRINT 
  80. 1122  PRINT "LENGTH LIMIT IS 40 CHARACTERS.": PRINT 
  81. 1125  PRINT D$"OPEN"F$",L40"
  82. 1130  PRINT D$"READ"F$",R0": INPUT P
  83. 1140  PRINT D$
  84. 1150  PRINT F$: INPUT A$
  85. 1160  IF  LEN(A$) >40  THEN  INVERSE : PRINT "LIMIT IS 40 CHARACTERS.": NORMAL : PRINT : GOTO 1150
  86. 1165  IF A$ = "END"  THEN  HOME : GOTO 1030
  87. 1170 P = P +1
  88. 1175  PRINT D$"OPEN"F$",L40"
  89. 1180  PRINT D$"WRITE"F$",R"P: PRINT A$
  90. 1190  PRINT D$"WRITE"F$",R0": PRINT P
  91. 1200  PRINT D$
  92. 1210  PRINT : PRINT : GOTO 1150
  93. 2000  REM  CREATE NEW DATA FILE
  94. 2010  HOME : PRINT  TAB( 10);: INVERSE : PRINT "CREATE NEW DATA FILE": NORMAL 
  95. 2020  PRINT : PRINT "THIS PORTION OF THE PROGRAM SHOULD"
  96. 2025  PRINT "BE USED TO CREATE NEW DATA FILES."
  97. 2030  PRINT "WHEN THE NECESSARY FILES HAVE BEEN"
  98. 2035  PRINT "CREATED, ENTERING '4' WILL RETURN"
  99. 2036  PRINT "CONTROL TO THE MAIN MENU.": PRINT 
  100. 2040  PRINT  TAB( 5)"1   CREATE NOUN FILE"
  101. 2050  PRINT  TAB( 5)"2   CREATE VERB FILE"
  102. 2060  PRINT  TAB( 5)"3   CREATE ADJECTIVE FILE"
  103. 2070  PRINT  TAB( 5)"4   QUIT"
  104. 2080  PRINT : PRINT "ENTER SELECTION NUMBER - ";: GET Z: PRINT Z
  105. 2090  IF Z <1  OR Z >4  THEN 2080
  106. 2091  IF Z = 1  THEN F$ = "NOUNS"
  107. 2092  IF Z = 2  THEN F$ = "VERBS"
  108. 2093  IF Z = 3  THEN F$ = "ADJECTIVES"
  109. 2095  IF Z = 4  THEN 50
  110. 2100  PRINT D$"OPEN"F$",L40"
  111. 2110  PRINT D$"WRITE"F$",R0": PRINT 0
  112. 2120  PRINT D$"CLOSE"
  113. 2130  HOME : GOTO 2040
  114. 3000  REM  INTRO PAGE
  115. 3005  HOME 
  116. 3010  VTAB 10: HTAB 12: INVERSE : PRINT "INTERSTELLAR NEWS"
  117. 3020  PRINT : PRINT " WITH THE LATEST NEWS FIRST FROM SPACE ": NORMAL 
  118. 3030  VTAB 23: PRINT "PRESS RETURN TO CONTINUE";: GET A$
  119. 3040  RETURN